Microzone & Northwoods Adventure (1984)(Scholastic)(Side A)[cr Black Bag - Club]
Emulation Item Preview
Share or Embed This Item
Microzone & Northwoods Adventure (1984)(Scholastic)(Side A)[cr Black Bag - Club]
- Language
- English
Notes
Disk info for Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do:
File Name: a2_Microzone_Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club/Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 1024
Used Space (bytes): 142336
Physical Size (KB): 140
Free Space (KB): 1
Used Space (KB): 139
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 4
Used Sectors: 556
Tracks On Disk: 35
Sectors On Disk: 16
Disk directory for Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do:
a2_Microzone_Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club/Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do DISK VOLUME #254
A 004 WH
A 004 HELLO2
A 019 TABLE OF CONTENTS
A 006 CREDITS SETUP
A 010 CREDITS
A 058 TWISTAPLOT
A 004 PROJECTOR CONTROL
A 004 LOAD PIC
B 020 APEX
B 010 PICDRAW
B 014 PICDRAWH
B 010 PROJECTOR
B 002 RUNPACK
B 010 BEE.SPC
B 008 CLOCK.SPC
B 006 CLOTHES.SPC
B 005 CRT.SPC
B 007 CUP.SPC
B 005 JUMP.SPC
B 009 MAZE.SPC
B 007 SHARP.SPC
B 006 SHRINK.SPC
B 007 WORKSHOP.SPC
B 036 MICROZONE ANIMATION
B 022 MICROZONE.2.S
B 002 ST.CURSOR
B 002 ST.TWIST
B 034 PIC.MARQUEE.A
B 034 PIC.WIZWARE
T 002 SIDE 1
T 071 TWISTAPLOT FILE
A 003 HELLO3
A 005 PPG
A 002 BB
B 026 PIC
B 002 DE
B 010 HI
A 002 ONE=^> DON'T UPDATE DOS <^=EYE
A 002 ONE=^> ITS AWESOME SLOW <^=EYE
A 002 ONE=^> DOS! THE CLUB/BB <^=EYE
DOS 3.3 format; 1,024 bytes free; 142,336 bytes used.
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/BB.bas:
10 REM BLACK BAG/THE CLUB
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/CREDITS SETUP.bas:
0 ONERR GOTO 62000
1 REM CREDITS SETUP
10 GOSUB 100
20 POKE 34,11: VTAB 24: PRINT : PRINT : PRINT : POKE 34,0
30 VTAB 23: HTAB 3: PRINT B$"C"U$" to see credits, "B$"RETURN"U$" to continue,": VTAB 24: HTAB 13: PRINT "or "B$"ESC"U$" to quit: ";: POKE -16368,0
40 VTAB 24: HTAB 29: GET X$: ON X$ = CHR$(13) GOTO 90: ON X$ = CHR$(27) GOTO 200: ON X$ = "C" OR X$ = "c" GOTO 50: GOTO 40
50 PRINT X$;
60 VTAB 24: HTAB 30: GET XX$: ON XX$ = CHR$(13) GOTO 70: VTAB 24: HTAB 29: PRINT " ";: GOTO 40
70 ESC = 1
80 VTAB 23: HTAB 1: PRINT SPC( 79);: VTAB 1: PRINT : PRINT CHR$(4)"RUNCREDITS"
81 GOTO 81
90 VTAB 23: HTAB 1: PRINT SPC( 79);: VTAB 1: PRINT : PRINT CHR$(4)"RUNTWISTAPLOT"
91 GOTO 91
100 H$ = CHR$(12):EL$ = CHR$(14):EP$ = CHR$(15):L$ = CHR$(17):R$ = CHR$(18) + CHR$(3) +"3":E$ = CHR$(5):W$ = CHR$(23):B$ = CHR$(25):U$ = CHR$(26)
110 CL$ = CHR$(3):WH$ = CL$ +"3":GU$ = CL$ +"1":VI$ = CL$ +"2":OU$ = CL$ +"5":BU$ = CL$ +"6"
120 CALL 3587: POKE 3594,28: POKE 3595,17
130 RETURN
200 VTAB 1: PRINT H$: VTAB 9: HTAB 7: PRINT "Take out the Wizware disk and": PRINT : HTAB 11: PRINT "turn off the computer.": PRINT : PRINT : PRINT : HTAB 10: PRINT "Or, put in another disk": PRINT : HTAB 12: PRINT "and press "B$"RETURN"U$": ";
210 SL = PEEK(47081)/16: IF SL <1 OR SL >7 THEN SL = 6
220 POKE -16368,0: GET X$: IF X$ < > CHR$(13) THEN 220
230 PRINT H$:A = (4096 *12) +(256 *SL): CALL A
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/CREDITS.bas:
0 ONERR GOTO 62000
1 REM
2 HIMEM: 38400
20 GOSUB 21000
99 REM
100 FOR I = 1 TO 8: READ X: POKE 7903 +I,X: NEXT
101 DATA 112,8,100,20,20,100,8,112
110 FOR I = 1 TO 8: READ X: POKE 8159 +I,X: NEXT
111 DATA 15,16,39,32,32,39,16,15
200 VTAB 1: HTAB 9: PRINT WI$GU$"CRACKED AND": PRINT : HTAB 9: PRINT "DISTRIBUTED BY"R$: PRINT
220 PRINT : HTAB 1: PRINT "ONE EYE - THE ATOM - BLUE ADEPT - THE FOX - THE SPROUT- AND SOME OTHER DUDES!"
225 PRINT : PRINT : HTAB 11: PRINT "BOARDS TO DIAL": PRINT : PRINT
227 PRINT : PRINT "THE THIEVES DEN.....512-441-9429": PRINT "POSSESION...........301-356-5895": PRINT "PIRATES CHEST.......617-891-1349": PRINT "STONEHENGE..........512-458-9008": PRINT "BLACK MARKET........615-377-6929"
228 PRINT "THE ARABIAN DEZERT..212-543-3923": PRINT "THE DINER...........512-443-3084"
240 GOSUB 900
300 HOME : HTAB 10: PRINT WI$VI$"FAMOUS QUOTES!"R$: PRINT : PRINT "DUDE WHO SAID IT........QUOTE!"
301 PRINT : PRINT "THE INTERN.....MAKE SURE IT WORX": PRINT "THE INTERN.....WHY DON'T YOU JUST RE- WRITE IT?": PRINT "THE GONIF......WHO'S ONE EYE?": PRINT "THE SAINT......I'M NO HESHER!"
302 PRINT "KRAC-MAN........IT HAS A SERIAL NUMBER": PRINT "KRAC-MAN........WHO CARES WHO WROTE IT?": PRINT "THE FOX.........GOTTA GO GOTTA GO K-BYE"
303 PRINT "THE ATOM........ROCKIN!": PRINT "THE SYNDICATE...AB CAN YOU HELP WITH THIS ONE?": PRINT "APPLE BANDIT....SURE I'LL HELP ON THIS ONE"
304 PRINT "APPLE BANDIT....DISK-FER //, ITS AWESOME": PRINT "MR. COPY ALL....GOT ANYTHING NEW?": PRINT "BLUE ADEPT......GUESS I'LL TALK TO YOU": PRINT "THE FREEZE......STUPID BUTTON"
390 GOSUB 900
400 VTAB 1: HTAB 7: PRINT WI$OU$"CLUB MEMBER LIST"R$: PRINT : PRINT
410 PRINT "ONE EYE": PRINT "THE ATOM": PRINT "CAMEL JOCKEY": PRINT "THE FOX": PRINT "THE SAINT": PRINT "DISK-MAN": PRINT "THE ACE": PRINT "THE BANDITO"
445 GOSUB 900
447 GOTO 990
449 REM RESTORE ASCII 92 & 124
450 POKE 7904,0: POKE 7905,0: POKE 7906,0: POKE 7907,0: POKE 7908,0: POKE 7909,8: POKE 7910,8: POKE 7911,4
460 POKE 8160,0: POKE 8161,0: POKE 8162,0: POKE 8163,8: POKE 8164,0: POKE 8165,8: POKE 8166,0: POKE 8167,0
469 RETURN
500 GOTO 990
650 GOSUB 450
690 GOSUB 900
699 RETURN
900 REM RETURN
905 GOSUB 910: GOTO 930
910 VTAB 24: HTAB 2: PRINT B$"RETURN"U$" to continue, or "B$"ESC"U$" to quit: ";: POKE -16368,0
920 GET CX$: IF CX$ = CHR$(27) THEN 990
925 IF CX$ < > CHR$(13) THEN 920
926 RETURN
930 PRINT H$
949 RETURN
990 VTAB 1: PRINT H$: GOSUB 450
999 PRINT : PRINT CHR$(4)"RUNTWISTAPLOT"
21000 REM APEX
21010 H$ = CHR$(12):R$ = CHR$(18) + CHR$(3) +"3":WI$ = CHR$(23):B$ = CHR$(25):U$ = CHR$(26):EP$ = CHR$(15)
21020 CL$ = CHR$(3):GU$ = CL$ +"1":VI$ = CL$ +"2":OU$ = CL$ +"5":BU$ = CL$ +"6"
21090 CALL 3584: POKE 3594,28: POKE 3595,17
21099 RETURN
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/HELLO2.bas:
0 ONERR GOTO 62000
1 REM HELLO2
10 PRINT CHR$(4)"MAXFILES 1"
20 HIMEM: 36096
25 H$ = CHR$(12):B$ = CHR$(25):U$ = CHR$(26):EP$ = CHR$(15)
30 D$ = CHR$(4): PRINT D$"BLOADPICDRAWH,A$8D00"
60 PRINT D$"BLOADAPEX,A$E00": CALL 3587: POKE 3594,28: POKE 3595,17
70 PRINT CHR$(4)"RUNTABLE OF CONTENTS"
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/HELLO3.bas:
0 ONERR GOTO 62000
1 REM HELLO3
10 PRINT CHR$(4)"MAXFILES 1"
20 HIMEM: 36096
25 H$ = CHR$(12):B$ = CHR$(25):U$ = CHR$(26):EP$ = CHR$(15)
80 POKE 103,1: POKE 104,8: POKE 2049,0
90 PRINT CHR$(4)"RUNPROJECTOR CONTROL"
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/LOAD PIC.bas:
0 ONERR GOTO 62000
1 REM LOAD PIC
2 HIMEM: 38250
15 POKE -16302,0
20 BO$ = CHR$(25):UN$ = CHR$(26)
40 FOR X = 1 TO 7: READ P$(X): NEXT
41 DATA X
42 DATA X
43 DATA UTILITIES
44 DATA X
45 DATA X
46 DATA X
47 DATA X
50 P = PEEK(3070)
55 PRINT CHR$(4)"BLOADRUNPACK,A38250"
60 PRINT CHR$(4)"BLOAD"P$(P)".PAK,D1"
70 HGR : POKE -16302,0: CALL 38250
80 POKE -16368,0
81 CALL 3587
85 IF P = 3 THEN GOSUB 200: VTAB 24: HTAB 1: PRINT SPC( 38);: VTAB 23: PRINT : VTAB 1: GOTO 110
90 IF Z >1200 THEN 110
100 IF PEEK( -16384) <128 THEN Z = Z +1: GOTO 90
110 PRINT CHR$(4)"RUN"P$(P)",D1": END
200 VTAB 23: HTAB 8: PRINT "Press "BO$"RETURN"UN$" to continue: ";: POKE -16368,0
210 VTAB 23: HTAB 34: GET X$: IF X$ < > CHR$(13) THEN 210
220 VTAB 23: HTAB 1: PRINT CHR$(15)
299 RETURN
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/ONE=^> DON'T UPDATE DOS <^=EYE.bas:
10 REM BLACK BAG/THE CLUB
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/ONE=^> ITS AWESOME SLOW <^=EYE.bas:
10 REM BLACK BAG/THE CLUB
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/PPG.bas:
5 POKE -16368,0
6 POKE 1011,69
100 TEXT : HOME
101 PRINT "BUT FIRST A WORD FROM THE DUDES!": PRINT : PRINT "HEY DUDES": PRINT : PRINT "CALL THE THIEVES DEN": PRINT "THE ULTIMATE BOARD": PRINT "ITS KICK...NEED I SAY MORE?": PRINT "CALL TODAY OR DON'T"
102 PRINT "512-441-9429"
103 IF PEEK( -16384) <127 THEN 103
110 PRINT " PPG HUNT INFO"
120 PRINT : PRINT " WHEN:"
130 PRINT " SATURDAY NOV. 24"
140 PRINT " WHERE:"
150 PRINT " THE 2 PAY PHONES AT CHEVRON STATION AT EDINGER AND BEACH": PRINT " (HUNTINGTON BEACH,CA.)"
160 PRINT " TIME:": PRINT " 11:00 AM - PIZZA PARTY AT 6:00 PM": PRINT " GREAT PRIZES!"
170 PRINT " CONTACT:": PRINT : PRINT " DR.MIRCO": PRINT " THE WOMBAT": PRINT " THE GONIF": PRINT : PRINT " TO REGISTER"
180 PRINT : PRINT : PRINT " (CALL BY FRIDAY)"
185 POKE 1011,69
190 PRINT "HIT RESET TO REBOOT!"
191 GOTO 191
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/PROJECTOR CONTROL.bas:
0 ONERR GOTO 62000
1 REM PROJECTOR CONTROL
10 PRINT CHR$(4);"MAXFILES 1"
20 PRINT CHR$(4);"BRUN PROJECTOR"
30 HIMEM: 22655
40 LOMEM: 16384
50 D$ = CHR$(13) + CHR$(4)
70 DIM TG%(2)
90 HGR : POKE 49234,0
100 TG%(0) = 0
110 PRINT D$;"BRUN MICROZONE ANIMATION"
120 TG%(1) = 412
130 TG%(2) = 567
140 CALL 24541
145 TG%(2) = 566
150 CALL 24541
155 CALL 3587: POKE 3594,28: POKE 3595,17
157 VTAB 7: HTAB 31: PRINT CHR$(25);"by": VTAB 9: HTAB 28: PRINT "Pat Relf"; CHR$(26)
160 VTAB 1: PRINT CHR$(4)"MAXFILES 3"
170 POKE 103,1: POKE 104,64: POKE 16384,0: POKE 768,253
180 PRINT CHR$(4)"RUNCREDITS SETUP"
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/RUNPACK.txt:
Offset Hex Data Characters
======= ================================================ =================
$000000 AD 00 60 85 04 A9 01 85 02 A9 60 85 03 A9 00 AA -.`..).. .)`..).*
$000010 85 05 A9 20 85 01 A5 05 85 00 A1 02 30 3A E6 02 ..) ..%. ..!.0:f.
$000020 D0 02 E6 03 A8 C8 A1 02 81 00 48 A5 00 18 65 04 P.f.(H!. ..H%..e.
$000030 85 00 90 08 E6 01 A5 01 C9 40 F0 0C 68 88 D0 E8 ....f.%. I@p.h.Ph
$000040 E6 02 D0 D6 E6 03 D0 D2 68 E6 02 D0 02 E6 03 E6 f.PVf.PR hf.P.f.f
$000050 05 A5 05 C5 04 D0 BB 60 49 80 A8 C8 E6 02 D0 02 .%.E.P;` I.(Hf.P.
$000060 E6 03 A1 02 81 00 E6 02 D0 02 E6 03 A5 00 18 65 f.!...f. P.f.%..e
$000070 04 85 00 90 08 E6 01 A5 01 C9 40 F0 D2 88 D0 E2 .....f.% .I@pR.Pb
$000080 F0 98 05 00 B9 40 02 99 90 02 C8 C0 10 D0 F5 A5 p...9@.. ..H@.Pu%
** END **
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/SIDE 1.txt:
1
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/ST.CURSOR.txt:
Offset Hex Data Characters
======= ================================================ =================
$000000 01 00 04 00 36 36 36 2E 24 24 24 2C 36 36 36 2E ....666. $$$,666.
$000010 24 24 24 2C 36 36 36 2E 24 24 24 2C 36 36 36 26 $$$,666. $$$,666&
$000020 00 .. .. .. .. .. .. .. .. .. .. .. .. .. .. .. .
** END **
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/ST.TWIST.txt:
Offset Hex Data Characters
======= ================================================ =================
$000000 02 00 0A 00 15 00 2B 00 00 00 6E 24 1F 35 36 FD ......+. ..n$.56}
$000010 27 24 04 00 14 40 09 36 25 2C 36 25 2C 24 36 36 '$...@.6 %,6%,$66
$000020 36 2C 24 24 2E 36 2C 04 00 .. .. .. .. .. .. .. 6,$$.6,. .
** END **
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/TABLE OF CONTENTS.bas:
0 ONERR GOTO 62000
1 REM TABLE OF CONTENTS
2 HIMEM: 38400
3 PRINT CHR$(4)"MAXFILES 3"
15 D$ = CHR$(4):BL$ = " "
20 CU = 1:LC = CU: GOSUB 21000
30 SIDE = 1
50 AP = ( PEEK( -1101) = 6):LK$ = CHR$(8):RK$ = CHR$(21):UK$ = CHR$(11):DK$ = CHR$(10):K1$ = "<":K2$ = ">": IF AP THEN K1$ = "`":K2$ = "~"
118 FOR I = 1 TO 2: READ SIDE(I): NEXT
119 DATA 1,2
120 FOR I = 1 TO 2: READ P$(I): NEXT
122 DATA PROJECTOR
124 DATA HELLO2
130 FOR I = 1 TO 2: READ PIC(I): NEXT
131 DATA 0,0
200 PRINT D$"BLOADPIC.MARQUEE.A,A$2000"
201 PRINT D$"BLOADST.CURSOR,A$300": POKE 232,0: POKE 233,3: SCALE= 1: ROT= 0
210 X(1) = 167:X(2) = 155:Y(1) = 106:Y(2) = 120: HCOLOR= 6: DRAW 1 AT X(1),Y(1)
215 VTAB 23: HTAB 2: PRINT WI$K1$RE$" or "WI$K2$RE$" to choose, "B$"RETURN"U$" when ready,"
216 VTAB 24: HTAB 13: PRINT "or "B$"ESC"U$" to quit: ";
217 POKE -16368,0: VTAB 24: HTAB 29: GET CX$
218 IF CX$ < > CHR$(13) AND CX$ < >LK$ AND CX$ < >RK$ AND CX$ < >UK$ AND CX$ < >DK$ AND CX$ < > CHR$(27) THEN 217
219 IF CX$ = CHR$(13) THEN 234
220 IF CX$ = CHR$(27) THEN CH = 0: GOTO 237
225 IF CX$ = UK$ OR CX$ = LK$ THEN CU = CU -1: IF CU = 0 THEN CU = 2
229 IF CX$ = DK$ OR CX$ = RK$ THEN CU = CU +1: IF CU = 3 THEN CU = 1
230 HCOLOR= 7: DRAW 1 AT X(LC),Y(LC): HCOLOR= 6: DRAW 1 AT X(CU),Y(CU):LC = CU: GOTO 217
234 CH = CU: POKE 3070,CH: IF SIDE(CH) < >SIDE THEN GOSUB 300: IF DER% THEN 237
236 IF CH < >0 THEN 241
237 PRINT HO$: VTAB 9: HTAB 7: PRINT "Take out the Wizware disk and": PRINT : HTAB 11: PRINT "turn off the computer.": PRINT : PRINT : PRINT : HTAB 10: PRINT "Or, put in another disk": PRINT : HTAB 12: PRINT "and press "B$"RETURN"U$": ";
238 SL = PEEK(47081)/16: IF SL <1 OR SL >7 THEN SL = 6
239 POKE -16368,0: GET X$: IF X$ < > CHR$(13) THEN 239
240 PRINT HO$:A = (4096 *12) +(256 *SL): CALL A: GOTO 240
241 IF P$(CH) = "PROJECTOR" THEN POKE 103,1: POKE 104,8: POKE 2049,0: PRINT HO$: PRINT CHR$(4)"RUNPROJECTOR CONTROL"
242 IF PIC(CH) THEN GOSUB 400: PRINT CHR$(4)"RUNLOAD PIC,D1": END
243 IF PIC(CH) THEN 243
244 GOSUB 400
245 POKE 3070,0
250 PRINT CHR$(4)"RUN"P$(CH)
251 GOTO 251
300 REM TURN OVER
310 HOME : PRINT HO$: VTAB 11: HTAB 4: PRINT "That program is on the other side.": PRINT : PRINT " Turn the disk over and press "B$"RETURN"U$": ";: POKE -16368,0
314 GET X$: IF X$ < > CHR$(13) THEN 314
316 PRINT HO$
320 DR% = 1:QX% = 2:VN$ = "SIDE " + STR$(SIDE(CH))
330 GOSUB 61000
340 PRINT
399 RETURN
400 HOME : VTAB 1: PRINT CHR$(12): VTAB 12: HTAB 10: PRINT "One moment, please...."
410 RETURN
21000 REM APEX
21010 HO$ = CHR$(12):EL$ = CHR$(14):EP$ = CHR$(15):LR$ = CHR$(17):RE$ = CHR$(18) + CHR$(3) +"3":EX$ = CHR$(5):WI$ = CHR$(23):B$ = CHR$(25):U$ = CHR$(26)
21020 CL$ = CHR$(3):WH$ = CL$ +"3":GU$ = CL$ +"1":VI$ = CL$ +"2":OU$ = CL$ +"5":BU$ = CL$ +"6":LAV$ = CL$ +"N"
21090 CALL 3584: POKE 3594,28: POKE 3595,17
21099 RETURN
61000 REM VERIFY DISK
61010 DER% = 0:QZ% = 0
61040 GOSUB 61200
61099 RETURN
61200 REM VERIFY
61210 ONERR GOTO 61300
61220 IF DER% = 0 THEN PRINT D$"VERIFY"VN$",D"DR%
61230 POKE 216,0
61299 RETURN
61300 REM VERIFY ERR
61310 QZ% = QZ% +1: IF QZ% >QX% THEN DER% = 1
61320 VTAB 10: HTAB 4: PRINT CHR$(7);"Can not read disk. Place Side "SI(CH)" of": PRINT : HTAB 1: PRINT "Adventure Double Feature into the drive": PRINT : HTAB 12: PRINT "and press "B$"RETURN"U$": ";: POKE -16368,0
61334 VTAB 14: HTAB 30: GET CX$: IF CX$ < > CHR$(13) THEN 61334
61336 PRINT HO$
61340 RESUME
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/TWISTAPLOT.bas:
0 ONERR GOTO 62000
1 REM TWISTAPLOT
20 HIMEM: 34048: GOSUB 10000: GOTO 7000
80 GOTO 80
90 CALL AN: CALL CL: FOR II = 1 TO 2000: NEXT :II = FRE(0): GOSUB 140: RETURN
95 CALL AN: CALL CL: GOSUB 150: RETURN
105 HCOLOR= 1:H1 = 1:H2 = 279: GOTO 125
110 HCOLOR= 2:H1 = 0:H2 = 278: GOTO 125
115 HCOLOR= 6:H1 = 0:H2 = 278: GOTO 125
120 HCOLOR= 5:H1 = 3:H2 = 277
125 V2 = (V *8) -4:V1 = 4: HPLOT H1,V1 TO H2,V1 TO H2,V2 TO H1,V2 TO H1,V1: CALL CL: HCOLOR= 3: RETURN
140 V = 23
141 V = 23: GOSUB 143: GOTO 144
143 VTAB V: HTAB 3: PRINT B$"RETURN"U$" to continue or ";B$"ESC"U$" to quit: ";: RETURN
144 POKE -16368,0: GET X$: IF X$ = ESC$ THEN X$ = "Q": PRINT H$: GOTO 192
147 IF X$ < > CHR$(13) THEN 144
148 VTAB 23: HTAB 1: PRINT SPC( 39);: VTAB 22: HTAB 1: PRINT : IF NOT FL THEN PRINT H$
149 RETURN
150 REM
152 FOR II = 1 TO 2000: NEXT :II = FRE(0): HCOLOR= 0: FOR YY = ((22) *8) -2 TO 23 *8: HPLOT 12,YY TO 267,YY: NEXT : HCOLOR= 3: GOTO 141
164 IF YY >500 OR PEEK(KB) >127 THEN PRINT H$: POKE -16368,0: RETURN
165 YY = YY +1: GOTO 164
170 REM
171 V = 8: PRINT H$: VTAB V -1: INVERSE :HU% = 0: FOR ZQ = 2 TO 40 STEP 2: HTAB ZQ:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: NEXT : PRINT R$;
172 FOR ZQ = V +1 TO V +9 STEP 2: VTAB ZQ: HTAB 2:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: HTAB 40: PRINT CL$;HU%(HU%);" ";: NEXT : VTAB ZQ -2: FOR ZQ = 2 TO 40 STEP 2: HTAB ZQ:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: NEXT : NORMAL : PRINT R$;
174 VTAB V +1: HTAB 1 +(40 - LEN(Q$))/2: PRINT B$;Q$;U$;: VTAB V +3: HTAB H: PRINT W$HU$;"1"R$" "X1$: PRINT : HTAB H: PRINT W$HU$"2"R$" "X2$: PRINT : HTAB 7: PRINT "Type "B$"1"U$" or "B$"2"U$", or "B$"ESC"U$" to quit: ";: POKE -16368,0: POKE 33,38
176 HTAB 36: PRINT " ";: HTAB 36: GET CH$: IF CH$ < >"1" AND CH$ < >"2" AND CH$ < >ESC$ THEN 176
177 IF CH$ = ESC$ THEN POKE 33,40: POP : PRINT H$: GOTO 192
178 PRINT CH$;: GET C$: IF C$ < > CHR$(13) THEN 176
179 POKE 33,40:CH = VAL(CH$): RETURN
180 REM
181 V = 8: PRINT H$: VTAB V -2: INVERSE :HU% = 0: FOR ZQ = 2 TO 40 STEP 2: HTAB ZQ:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: NEXT : PRINT R$;: FOR ZQ = V TO V +11 STEP 2: VTAB ZQ: HTAB 2:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: HTAB 40: PRINT CL$;HU%(HU%);" ";
183 NEXT : VTAB ZQ -2: FOR ZQ = 2 TO 40 STEP 2: HTAB ZQ:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: NEXT : NORMAL : PRINT R$;: VTAB V: HTAB 1 +(40 - LEN(Q$))/2: PRINT B$;Q$;U$;
185 VTAB V +2: HTAB H: PRINT W$OU$;"1"R$" "Z1$: PRINT : HTAB H: PRINT W$OU$"2"R$" "Z2$: PRINT : HTAB H: PRINT W$OU$"3"R$" "Z3$: PRINT : HTAB 6: PRINT "Type "B$"1"U$", "B$"2"U$" or "B$"3"U$", or "B$"ESC"U$" to quit: ";: POKE -16368,0: POKE 33,39
186 HTAB 38: PRINT " ";: HTAB 38: GET CH$: IF CH$ < >"1" AND CH$ < >"2" AND CH$ < >"3" AND CH$ < >ESC$ THEN 186
187 IF CH$ = ESC$ THEN POKE 33,40: POP : PRINT H$: GOTO 192
188 PRINT CH$;: GET C$: IF C$ < > CHR$(13) THEN 186
189 POKE 33,40:FI = VAL(CH$): PRINT H$: RETURN
190 PRINT : PRINT : PRINT : HTAB 14: PRINT L$;CL$;HU%(BOX)"THE END"R$: GOSUB 140
192 VTAB 11: HTAB 8: PRINT "Do you want to enter the": PRINT : HTAB 8: PRINT "Microzone again? (";B$;"Y"U$"/"B$"N"U$"): ";: POKE -16368,0
193 VTAB 13: HTAB 32: GET X$: IF X$ < >"Y" AND X$ < >"N" THEN PRINT BE$;: GOTO 193
194 PRINT X$;
195 GET CX$: IF CX$ = CHR$(8) THEN PRINT CX$;" ";CX$;: GOTO 193
196 IF CX$ = CHR$(13) THEN PRINT H$: GOTO 198
197 PRINT BE$;: GOTO 195
198 IF X$ = "Y" THEN 7000
199 GOTO 20000
200 REM
202 V = 7: PRINT H$: VTAB V -1: INVERSE :HU% = 0: FOR ZQ = 2 TO 40 STEP 2: HTAB ZQ:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: NEXT : PRINT R$;: FOR ZQ = V +1 TO V +11 STEP 2: VTAB ZQ: HTAB 2:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: HTAB 40: PRINT CL$;HU%(HU%);" ";
206 NEXT : VTAB ZQ -2: FOR ZQ = 2 TO 40 STEP 2: HTAB ZQ:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: NEXT : NORMAL : PRINT R$;: VTAB V +1: HTAB 1 +(40 - LEN(Q$))/2: PRINT B$;Q$;U$;: RETURN
220 GOSUB 200: VTAB V +3: HTAB H: PRINT W$HU$;"1"R$" "X1$: HTAB H +3: PRINT X2$: PRINT : HTAB H: PRINT W$HU$;"2"R$" "X3$: HTAB H +3: PRINT X4$: GOTO 250
230 GOSUB 200: VTAB V +4: HTAB H: PRINT W$HU$;"1"R$" "X1$: HTAB H +3: PRINT X2$: PRINT : HTAB H: PRINT W$HU$;"2"R$" "X3$: GOTO 250
240 GOSUB 200: VTAB V +4: HTAB H: PRINT W$HU$;"1"R$" "X1$: PRINT : HTAB H: PRINT W$HU$;"2"R$" "X2$: HTAB H +3: PRINT X3$
250 PRINT : HTAB 7: PRINT "Type "B$"1"U$" or "B$"2"U$", or "B$"ESC"U$" to quit: ";: POKE -16368,0: POKE 33,38
255 HTAB 36: PRINT " ";: HTAB 36: GET CH$: IF CH$ < >"1" AND CH$ < >"2" AND CH$ < >ESC$ THEN 255
260 POKE 33,39: IF CH$ = ESC$ THEN POKE 33,40: PRINT H$: GOTO 192
265 PRINT CH$;: GET C$: IF C$ < > CHR$(13) THEN 255
298 POKE 33,40:CH = VAL(CH$): RETURN
300 PRINT : FOR X = 1 TO 8:A$(X) = "": NEXT : FOR X = 1 TO NR%(N):R = SR%(N) +X -1: PRINT D$"READ"F$",R"R: INPUT A$(X): NEXT : PRINT D$: PRINT H$: IF N = 89 THEN LA = 7:A$(6) = "up and down on the keys to type":A$(7) = "'bbiigg" + CHR$(34) +".": GOTO 325
310 IF N = 5 OR N = 40 THEN RETURN
311 IF N = 12 THEN A$(6) = "start over.":LA = 6: GOTO 325
312 IF N = 88 THEN A$(7) = "computer." +QU$:LA = 7: GOTO 325
313 IF N = 75 THEN A$(3) = A$(3) +" Normal Size, Returning To"
314 IF N = 43 THEN A$(6) = CHR$(34) + RIGHT$(A$(6), LEN(A$(6)) -1)
315 IF N = 46 THEN A$(3) = "you fall inside the manual. The":A$(4) = "cover flips down on you and you are":A$(5) = "squashed flat. You make a very":A$(6) = "cute little bookmark.":LA = 6: GOTO 325
317 IF N = 68 THEN A$(3) = A$(3) +": Maybe you"
318 IF N = 73 THEN A$(3) = "There's just you and a few unhappy":A$(4) = "moths inside. You'll probably get":A$(5) = "used to the smell.":LA = 5: GOTO 325
319 IF N = 6 THEN A$(7) = "-- and fast! But how?":LA = 7: GOTO 325
320 IF N = 54 THEN A$(3) = "comes after you. She bats her paw":A$(4) = "at the bedspread, narrowly missing":A$(5) = "your cheek.":LA = 5: GOTO 325
321 IF N = 66 THEN A$(5) = "ticking.":LA = 5: GOTO 325
322 IF N = 75 THEN A$(3) = A$(3) +":"
323 IF N = 39 THEN A$(6) = A$(6) +":"
324 LAST = NR%(N)
325 FOR X = 1 TO LAST: IF LEFT$(A$(X),1) = "'" AND LEFT$(A$(X),3) < >"'pe" THEN A$(X) = CHR$(34) + RIGHT$(A$(X), LEN(A$(X)) -1)
330 VTAB (X *2) +1: HTAB 4 -( LEFT$(A$(X) +" ",1) = CHR$(34)): PRINT A$(X): NEXT :V = (LAST *2) +3:BOX = BOX +1: IF BOX >4 THEN BOX = 1
390 ON BOX GOSUB 105,110,120,115: RETURN
400 GOSUB 410: GOTO 422
410 PIC$ = "MAZE": GOSUB 9000: CALL AN: CALL CL: HCOLOR= 0: FOR YY = 70 TO 72: HPLOT 185,YY TO 192,YY: NEXT : SCALE= 1: ROT= 0: HCOLOR= 3: DRAW 2 AT 250,25: ROT= 16: DRAW 2 AT 201,148: DRAW 2 AT 170,148: ROT= 32: DRAW 2 AT 14,134: ROT= 0: RETURN
422 ROT= 0:X = 42:LX = 42:Y = 4:LY = 4
425 VTAB 21: IF AP THEN HTAB 1: PRINT "Use arrow keys to move.";: GOTO 430
426 HTAB 2: PRINT "Use "B$"I"U$", "B$"J"U$", "B$"K"U$" and "B$"M"U$" keys": PRINT : HTAB 2: PRINT "to move.";
430 FOR ZZ = 1 TO 10: XDRAW 1 AT X,Y: FOR ZX = 1 TO 200: NEXT : XDRAW 1 AT X,Y: FOR ZX = 1 TO 200: NEXT : NEXT : XDRAW 1 AT X,Y: POKE -16368,0
432 WAIT KB,128:X$ = CHR$( PEEK(KB) -128): POKE -16368,0: IF X$ = ESC$ THEN PRINT H$: GOTO 192
438 IF X$ = RK$ AND X <274 THEN X = X +4: GOTO 455
440 IF X$ = LK$ AND X >6 THEN X = X -4: GOTO 455
445 IF X$ = UK$ AND Y >6 THEN Y = Y -4: GOTO 455
450 IF X$ = DK$ AND Y <180 THEN Y = Y +4: GOTO 455
451 PRINT BE$;: GOTO 432
455 XDRAW 1 AT LX,LY: XDRAW 1 AT X,Y: IF Y = 76 AND (X = 198 OR X = 202) AND X$ = DK$ THEN XDRAW 1 AT X,Y: FOR K = 76 TO 128 STEP 4: XDRAW 1 AT X,K:Z = PEEK(SD) + PEEK(SD) - PEEK(SD) + PEEK(SD): XDRAW 1 AT X,K: FOR Z = 1 TO 90: NEXT : NEXT :Y = 128: XDRAW 1 AT X,Y: GOTO 485
461 IF Y = 124 AND (X = 198 OR X = 202) AND X$ = UK$ THEN XDRAW 1 AT X,Y: FOR K = 120 TO 72 STEP -4: XDRAW 1 AT X,K:Z = PEEK(SD) + PEEK(SD) - PEEK(SD) + PEEK(SD): XDRAW 1 AT X,K: FOR Z = 1 TO 90: NEXT : NEXT :Y = 72: XDRAW 1 AT X,Y: GOTO 485
462 IF Y = 140 AND X = 142 AND X$ = RK$ THEN XDRAW 1 AT X,Y: FOR K = 146 TO 174 STEP 4: XDRAW 1 AT K,Y:Z = PEEK(SD) + PEEK(SD) - PEEK(SD) + PEEK(SD): XDRAW 1 AT K,Y: FOR Z = 1 TO 90: NEXT : NEXT :X = 174: XDRAW 1 AT X,Y: GOTO 485
463 IF Y = 140 AND X = 170 AND X$ = LK$ THEN XDRAW 1 AT X,Y: FOR K = 166 TO 138 STEP -4: XDRAW 1 AT K,Y:Z = PEEK(SD) + PEEK(SD) - PEEK(SD) + PEEK(SD): XDRAW 1 AT K,Y: FOR Z = 1 TO 90: NEXT : NEXT :X = 138: XDRAW 1 AT X,Y: GOTO 485
465 IF (X = 34 AND Y = 28) OR (Y = 64 AND (X = 210 OR X = 230)) OR (Y = 88 AND (X = 186 OR X = 190)) THEN 1000
470 IF X = <14 AND (Y >131 AND Y <145) THEN 2000: REM
472 IF X = >246 AND Y = 24 THEN 2010: REM
474 IF X = 174 AND Y = 148 THEN 2060: REM
476 IF X = 202 AND Y = 148 THEN 2070: REM
480 IF PEEK(234) < >16 THEN XDRAW 1 AT X,Y: XDRAW 1 AT LX,LY:X = LX:Y = LY: PRINT BE$;: GOTO 432
485 LX = X:LY = Y: GOTO 432
500 VTAB 22:SKIP = 0: HTAB 9: PRINT "Press "B$"RETURN"U$" to continue,": HTAB 8: PRINT B$"S"U$" to skip, or "B$"ESC"U$" to quit: ";: POKE -16368,0
520 VTAB 23: HTAB 35: GET X$: IF X$ = ESC$ THEN PRINT H$: GOTO 192
540 IF X$ = "S" THEN 560
550 IF X$ < > CHR$(13) THEN 520
555 RETURN
560 PRINT X$;: GET XX$: IF XX$ < > CHR$(13) THEN VTAB 23: HTAB 35: PRINT " ";: GOTO 520
580 SKIP = 1: RETURN
600 GOSUB 610: GOTO 620
610 FOR XX = 1 TO 60: POKE PI, INT( RND(1) *254) +1: POKE DUR,5: POKE -16299,0: CALL MUS: POKE -16300,0: NEXT : RETURN
620 X$ = " YOU ARE ABOUT TO ENTER": IF M2 THEN X$ = "YOU ARE ABOUT TO LEAVE"
630 X$ = B$ +X$ +U$:Y$ = L$ +VI$ +"THE MICROZONE" +R$: VTAB 11: HTAB 1 +(40 - LEN(X$))/2: PRINT X$: VTAB 14: HTAB 7: PRINT Y$: FOR XX = 1 TO 3000: NEXT :XX = FRE(0): PRINT H$: GOSUB 610: PRINT H$: RETURN
1000 PRINT H$:N = 12: GOSUB 300:HU$ = OU$: GOTO 190
2000 PRINT H$:N = 13: GOSUB 300: GOTO 190
2010 PRINT H$:N = 14: GOSUB 300: GOSUB 140:H = 4:X1$ = "Fight the spider.":X2$ = "Run back into the maze to get":X3$ = "away.":HU$ = GU$: GOSUB 240: IF CH = 1 THEN N = 15: GOSUB 300: GOSUB 140:N = 80: GOSUB 300: GOSUB 140:X = 242:Y = 24:LX = 242:LY = 24: GOSUB 410: SCALE= 1: ROT= 0: GOTO 425
2040 N = 81: GOSUB 300: GOSUB 140: IF FI < >3 THEN N = 82: GOSUB 300: GOTO 190
2050 N = 83: GOSUB 300: GOSUB 140:X = 242:Y = 24:LX = 242:LY = 24: GOSUB 410: GOTO 425
2060 N = 17: GOSUB 300: GOSUB 140: GOTO 2480
2070 VTAB 23: HTAB 1: PRINT H$:N = 18: GOSUB 300:PIC$ = "CUP": GOSUB 9000: GOSUB 500: IF SK THEN 2080
2075 GOSUB 95
2080 X1$ = "Push the cup off the manual.":X2$ = "Pull the manual out from under":X3$ = "the cup.":H = 5:HU$ = OU$: GOSUB 240: IF CH = 2 THEN 2100
2090 N = 19: GOSUB 300: GOTO 190
2100 N = 21: GOSUB 300: GOSUB 140:X1$ = "Turn a few pages at a time to":X2$ = "reach the glossary.":X3$ = "Turn directly to the glossary.":H = 6:HU$ = VI$: GOSUB 230: IF CH = 1 AND FI = 3 THEN 2120
2115 IF CH = 1 AND FI < >3 THEN 2130
2116 IF CH = 2 AND FI < >3 THEN 2140
2117 IF CH = 2 AND FI = 3 THEN 2140
2118 GOTO 2130
2120 N = 22: GOSUB 300: GOSUB 140: PRINT H$: HCOLOR= 3: HPLOT 0,0 TO 279,0 TO 279,163 TO 0,163 TO 0,0: VTAB 2: HTAB 3: PRINT E$WH$"Big, getting"R$: PRINT : PRINT : HTAB 3: PRINT "Just press the "B$"SHIFT"U$" key, of course.": PRINT : PRINT : HTAB 3: PRINT E$"Bugs, biting"R$: PRINT : PRINT : HTAB 3: PRINT "The biggest bug in this program is": HTAB 3: PRINT "an amazing spider."
2126 PRINT : PRINT : HTAB 3: PRINT E$"Bytes, avoiding"R$: PRINT : PRINT : HTAB 3: PRINT "Don't run away from computer bugs.": HTAB 3: PRINT "Stay and dance a while.": GOSUB 140:N = 24: GOSUB 300: GOSUB 140:M2 = 1: GOSUB 600:N = 25: GOSUB 300: GOTO 190
2130 N = 26: GOSUB 300: GOSUB 140:N = 27: GOSUB 300: GOSUB 140:N = 28: GOSUB 300: GOSUB 140:M2 = 1: GOSUB 600:N = 84: GOSUB 300: GOSUB 140:N = 85: GOSUB 300: GOTO 190
2140 N = 86: GOSUB 300: GOTO 190
2150 N = 29: GOSUB 300: GOSUB 140:X1$ = "Climb up the cord.":X2$ = "Shinny up the leg.":HU$ = BU$:H = 11: GOSUB 170: IF CH = 2 THEN 2180
2170 N = 30: GOSUB 300:PIC$ = "SHARP": GOSUB 9000: GOSUB 500: IF SK THEN 2190
2172 GOSUB 95:N = 108: GOSUB 300: GOSUB 500: IF SK THEN 2190
2175 N = 31: GOSUB 300: GOSUB 500: IF SK THEN 2190
2180 N = 59: GOSUB 300: GOSUB 500: IF SK THEN 2190
2185 N = 87: GOSUB 300:PIC$ = "JUMP": GOSUB 9000: GOSUB 500: IF SK THEN 2190
2186 GOSUB 95: PRINT H$:A$(1) = "Suddenly, you hear someone!":LA = 1: GOSUB 325: GOSUB 140
2190 X1$ = "Hide in a big straw for drinking":X2$ = "cherry slush.":X3$ = "Hurry to look in the manual for":X4$ = "the way to get big again.":H = 4:HU$ = OU$: GOSUB 220: IF CH = 2 THEN 2250
2210 N = 33: GOSUB 300: GOSUB 500: IF SK THEN 2220
2215 N = 34: GOSUB 300: GOSUB 140
2220 X1$ = "Scream at him that he can't get":X2$ = "away with it.":X3$ = "Stay hidden.":H = 4: GOSUB 230: IF CH = 2 THEN 2240
2230 N = 35: GOSUB 300: GOSUB 140:N = 36: GOSUB 300: GOTO 190
2240 N = 88: GOSUB 300: GOSUB 140:N = 89: GOSUB 300: GOSUB 140:M2 = 1: GOSUB 600:N = 90: GOSUB 300: GOSUB 140:N = 91: GOSUB 300: GOTO 190
2250 N = 38: GOSUB 300: GOSUB 140:X1$ = "Turn a few pages at a time to":X2$ = "reach the glossary.":X3$ = "Turn directly to the glossary.":H = 5:HU$ = GU$: GOSUB 230: IF CH = 1 AND FI = 3 THEN 2270
2263 IF CH = 1 AND FI < >3 THEN 2320
2264 IF CH = 2 AND FI = 3 THEN 2330
2265 GOTO 2320
2270 N = 39: GOSUB 300: GOSUB 140:N = 40: GOSUB 300: PRINT H$: HCOLOR= 3: HPLOT 0,0 TO 279,0 TO 279,140 TO 0,140 TO 0,0: VTAB 3: HTAB 3: PRINT E$;WH$;A$(1);R$: VTAB 6: FOR II = 2 TO 5: HTAB 3: PRINT A$(II): PRINT : NEXT : GOSUB 140:N = 41: GOSUB 300: GOSUB 140:N = 42: GOSUB 300: GOSUB 140:M2 = 1: GOSUB 600
2310 N = 43: GOSUB 300: GOTO 190
2320 N = 44: GOSUB 300: GOTO 190
2330 N = 45: GOSUB 300: GOTO 190
2350 N = 47: GOSUB 300: GOSUB 500: IF SK THEN 2370
2360 N = 48: GOSUB 300:PIC$ = "CLOTHES": GOSUB 9000: GOSUB 500: IF SK THEN 2370
2365 GOSUB 95
2370 X1$ = "Dig through the mountain of":X2$ = "clothes.":X3$ = "Climb the mountain of clothes.":H = 4:HU$ = VI$: GOSUB 230: IF CH = 2 THEN 2580
2380 N = 92: GOSUB 300: GOSUB 500: IF SK THEN 2400
2390 N = 93: GOSUB 300: GOSUB 140
2400 X1$ = "Try explaining things to":X2$ = "Yonkers.":X3$ = "Dig back to the door.":H = 6:HU$ = OU$: GOSUB 230: IF CH = 2 THEN 2440
2410 N = 49: GOSUB 300: GOSUB 140:N = 50: GOSUB 300: GOSUB 140:M2 = 1: GOSUB 600:N = 51: GOSUB 300: GOTO 190
2440 N = 52: GOSUB 300: GOSUB 140:X1$ = "Search for the manual under":X2$ = "the bed.":X3$ = "Climb up onto the bed and look":X4$ = "on your night table.":H = 5:HU$ = VI$: GOSUB 220: IF CH = 2 THEN 2520
2470 N = 56: GOSUB 300: GOSUB 140
2480 N = 57: GOSUB 300: GOSUB 140:N = 58: GOSUB 300: GOSUB 140:PIC$ = "BEE": GOSUB 9000: GOSUB 95:N = 32: GOSUB 300: GOSUB 140:N = 60: GOSUB 300: GOTO 190
2520 N = 61: GOSUB 300: GOSUB 140: IF RND(1) *10 <6 THEN 2550
2530 N = 62: GOSUB 300: GOSUB 140:N = 63: GOSUB 300: GOSUB 140:N = 64: GOSUB 300: GOTO 190
2550 N = 94: GOSUB 300: GOSUB 140:N = 95: GOSUB 300:PIC$ = "CLOCK": GOSUB 9000: GOSUB 140: GOSUB 90:N = 96: GOSUB 300: GOSUB 140:N = 97: GOSUB 300: GOSUB 140:N = 98: GOSUB 300:PIC$ = "CRT": GOSUB 9000: GOSUB 140: GOSUB 90:N = 99: GOSUB 300: GOSUB 140:M2 = 1: GOSUB 600:N = 100: GOSUB 300: GOTO 190
2580 N = 67: GOSUB 300: GOSUB 140:Q$ = "Which do you want to explore?":X1$ = "The chemistry set.":X2$ = "The shoes and boots.":H = 10:HU$ = GU$: GOSUB 170:Q$ = OQ$: IF CH = 2 THEN 2640
2600 N = 68: GOSUB 300: GOSUB 140:N = 69: GOSUB 300: GOSUB 140:N = 70: GOSUB 300: GOSUB 140:N = 71: GOSUB 300: GOSUB 140:N = 72: GOSUB 300: GOTO 190
2640 N = 78: GOSUB 300: GOSUB 140:X1$ = "Climb into the boot to rock":X2$ = "it off the manual.":X3$ = "Push the boot off the manual.":H = 5:HU$ = VI$: GOSUB 230: IF CH = 2 THEN 2670
2660 N = 74: GOSUB 300: GOSUB 140:N = 101: GOSUB 300: GOTO 190
2670 N = 102: GOSUB 300: GOSUB 500: IF SK THEN 2680
2674 N = 103: GOSUB 300: GOSUB 500: IF SK THEN 2680
2677 N = 104: GOSUB 300: GOSUB 140
2680 X1$ = "Turn a few pages at a time to":X2$ = "reach the glossary.":X3$ = "Turn directly to the glossary.":H = 5:HU$ = OU$: GOSUB 230: IF FI = 3 AND CH = 1 THEN 2690
2684 IF FI = 3 AND CH = 2 THEN 2730
2686 GOTO 2720
2690 N = 75: GOSUB 300: GOSUB 140:N = 77: GOSUB 300: GOSUB 140:M2 = 1: GOSUB 600:N = 76: GOSUB 300: GOTO 190
2720 N = 105: GOSUB 300: GOSUB 140:N = 106: GOSUB 300: GOSUB 140: GOTO 2690
2730 N = 107: GOSUB 300: GOTO 190
7000 REM
7002 VTAB 12: HTAB 1: PRINT "Do you want instructions? ("B$"Y"U$"/"B$"N"U$"): ";: POKE -16368,0
7003 VTAB 12: HTAB 34: GET X$: IF X$ < >"Y" AND X$ < >"N" THEN PRINT BE$;: GOTO 7003
7004 PRINT X$;
7005 VTAB 12: HTAB 35: GET XX$: IF XX$ = CHR$(13) THEN 7008
7006 IF XX$ = CHR$(8) THEN PRINT XX$;" ";: GOTO 7003
7007 PRINT BE$;: GOTO 7005
7008 PRINT : IF X$ = "Y" THEN GOSUB 7900
7010 N = 1: GOSUB 300: GOSUB 500: IF SK THEN 7030
7020 N = 2: GOSUB 300: GOSUB 140
7030 Q$ = "What do you want for breakfast?":HU$ = OU$:Z1$ = "Nothing":Z2$ = "Goopy Gumpy candy, Kumquat Kola":Z3$ = "Eggs, toast, orange juice, milk":H = 4: GOSUB 180:Q$ = OQ$: IF FI >1 THEN VTAB 12: HTAB 10: PRINT GU$;W$;"Umm."R$;" That was good.": GOSUB 500: IF SK THEN 7110
7050 N = 3: GOSUB 300: GOSUB 500: IF SK THEN 7110
7060 PRINT H$:M2 = 0: GOSUB 600:N = 4: GOSUB 300: GOSUB 500: IF SK THEN 7110
7080 N = 5: GOSUB 300:PIC$ = "SHRINK": GOSUB 9000: CALL AN: CALL CL: VTAB 21: HTAB 4: PRINT A$(1): GOSUB 140:N = 6: GOSUB 300: GOSUB 500: IF SK THEN 7110
7100 N = 7: GOSUB 300: GOSUB 140
7110 HU$ = VI$:Q$ = " Where do you look for the manual?":X1$ = "In your grandfather's workshop.":X2$ = "In your bedroom.":H = 5: GOSUB 170:Q$ = OQ$: IF CH = 2 THEN 2350
7130 N = 8: GOSUB 300: GOSUB 500: IF SK THEN 7160
7140 N = 9: GOSUB 300:PIC$ = "WORKSHOP": GOSUB 9000: GOSUB 140: GOSUB 90:N = 10: GOSUB 300: GOSUB 140
7160 Q$ = OQ$:HU$ = BU$:H = 4:X1$ = "Search through the straws for":X2$ = "the manual.":X3$ = "Climb onto your grandfather's":X4$ = "workbench for a better view.": GOSUB 220: IF CH = 2 THEN GOTO 2150
7180 N = 11: GOSUB 300: GOSUB 140: GOTO 400
7900 REM
7905 PRINT H$: VTAB 9: HTAB 9: PRINT "You are about to enter a": PRINT : PRINT : HTAB 6: PRINT W$OU$"Twistaplot"R$"{} story.": GOSUB 140
7910 PRINT H$: VTAB 4: HTAB 1: PRINT B$"You"U$" are the star of the story and "B$"you"U$: PRINT : PRINT "are in control.": PRINT : PRINT : PRINT : PRINT "There are many possible endings to your": PRINT : PRINT "micro-adventure. "B$"You"U$" decide which way": PRINT : PRINT "to go. When you are given a choice,"
7930 PRINT : PRINT "type the number of your choice and": PRINT : PRINT "press "B$"RETURN"U$".": GOSUB 140: VTAB 5: HTAB 6: PRINT "Here is your chance to practice!":HU$ = OU$:X1$ = "Read instructions again.":X2$ = "Start the story."
7990 H = 7:V = 10: VTAB V -1: INVERSE :HU% = 0: FOR ZQ = 2 TO 40 STEP 2: HTAB ZQ:HU% = HU% +1 -4 *(HU% = 4): PRINT CL$;HU%(HU%);" ";: NEXT : PRINT R$;:Q$ = OQ$: GOSUB 172: IF CH = 1 THEN 7900
7998 PRINT H$: RETURN
9000 REM
9005 VTAB 23: PRINT : PRINT D$"BLOAD"PIC$".SPC,D1,A"L1:H1 = L1 - INT(L1/256) *256:L0 = INT(L1/256): POKE 36352,H1: POKE 36353,L0: RETURN
10000 GOSUB 10100: GOSUB 10200: GOSUB 10900: GOSUB 21000: PRINT D$"OPEN"F$",D1,L"L: PRINT D$: RETURN
10100 FOR I = 1 TO 4: READ HU%(I): NEXT : DATA 2,5,6,1:D$ = CHR$(4):QU$ = CHR$(34):BAK$ = CHR$(8):KB = -16384:ESC$ = CHR$(27):FT% = 1:BE$ = CHR$(7):SD = -16336:BL$ = " "
10127 OQ$ = "What do you want to do?":AN = 36400:L1 = 34048:F$ = "TWISTAPLOT FILE":L = 37:D = 1:AP = ( PEEK( -1101) = 6):RK$ = "K":LK$ = "J":UK$ = "I":DK$ = "M": IF AP THEN RK$ = CHR$(21):LK$ = CHR$(8):UK$ = CHR$(11):DK$ = CHR$(10)
10198 RETURN
10200 NN = 108: DIM SR%(NN),NR%(NN): FOR I = 1 TO NN: READ SR%(I): NEXT : FOR I = 1 TO NN: READ NR%(I): NEXT : DATA 1,5,10,16,20,21,27,30,35,39: DATA 41,47,52,57,61,65,479,71,74,77: DATA 82,86,92,95,98,103,106,111,120,124
10214 DATA 128,136,142,145,152,158,161,166,169,175: DATA 180,186,190,197,203,207,209,212,215,221: DATA 228,233,231,235,237,240,245,250,253,258: DATA 264,266,273,278,279,281,285,290,295,299
10218 DATA 304,308,311,313,317,321,327,332,337,345: DATA 350,354,360,115,365,371,133,378,384,389: DATA 394,399,405,411,416,421,427,433,438,443: DATA 337,448,453,458,464,469,474,238
10231 DATA 4,5,6,4,1,6,3,5,4,2: DATA 6,5,5,4,6,5,5,3,7,5: DATA 4,5,3,3,5,3,5,4,4,3: DATA 5,6,3,7,6,4,5,3,6,5: DATA 5,4,7,6,6,2,3,3,6,7: DATA 5,5,4,2,3,4,5,3,5,6: DATA 2,7,5,6,2,4,5,5,3,5: DATA 4,5,2,4,4,6,5,5,8,5
10239 DATA 4,6,5,3,6,7,2,6,5,5: DATA 5,6,6,5,5,5,6,5,5,5: DATA 6,5,5,6,5,5,5,2: RETURN
10900 PRINT D$"BLOADST.TWIST,A870": POKE 232,102: POKE 233,3: PRINT D$"BLOADPICDRAW,A$8E00": FOR I = 1 TO 35: READ J: POKE 799 +I,J: NEXT :CL = 800: DATA 169,32,133,255,169,127,133,254,160,0,152,145,254,24,165,254,105,128,133,254,144,2,230,255,201,127,208,238,165,255,201,64,208,232,96
10930 FOR I = 1 TO 21: READ J: POKE 847 +I,J: NEXT :MU = 848:PI = 839:DUR = 838: DATA 173,48,192,136,208,5,206,70,3,240,9,202,208,245,174,71,3,76,80,3,96: RETURN
20000 PRINT H$: VTAB 11: HTAB 9: PRINT "Do you want to enter": PRINT : HTAB 9: PRINT "the Northwoods? (";B$;"Y"U$"/"B$"N"U$"): ";: POKE -16368,0
20010 VTAB 13: HTAB 32: GET X$: IF X$ < >"Y" AND X$ < >"N" THEN PRINT BE$;: GOTO 20010
20020 PRINT X$;
20030 GET CX$: IF CX$ = CHR$(8) THEN PRINT CX$;" ";CX$;: GOTO 20010
20040 IF CX$ = CHR$(13) THEN PRINT H$: GOTO 20060
20050 PRINT BE$;: GOTO 20030
20060 IF X$ = "N" THEN 20200
20070 PRINT H$: VTAB 11: HTAB 3: PRINT "Turn the disk over and press "B$"RETURN"U$": ";:QZ% = 0: POKE -16368,0: ONERR GOTO 20130
20080 GET X$: IF X$ < > CHR$(13) THEN 20080
20090 PRINT : PRINT D$"VERIFY SIDE 2": GOTO 20140
20130 POKE 216,0:QZ% = QZ% +1: IF QZ% = >5 THEN 62000
20135 PRINT H$: VTAB 10: PRINT BE$" Cannot read the disk. Place side 2 of": PRINT : PRINT "Adventure Double Feature into the drive": PRINT : HTAB 12: PRINT "and press "B$"RETURN"U$": ";: POKE -16368,0: ONERR GOTO 20130
20139 GOTO 20080
20140 PRINT : PRINT H$: VTAB 11: HTAB 10: PRINT "One moment, please...": PRINT CHR$(4)"RUN HELLO2"
20141 GOTO 20141
20200 SL = PEEK(47081)/16: IF SL <1 OR SL >6 THEN SL = 6
20210 PRINT H$: VTAB 9: HTAB 9: PRINT "Take out the Wizware disk": PRINT : HTAB 9: PRINT "and turn off the computer.": PRINT : PRINT : PRINT : HTAB 10: PRINT "Or, put in another disk": PRINT : HTAB 12: PRINT "and press "B$"RETURN"U$": ";: POKE -16368,0
20220 GET X$: IF X$ < > CHR$(13) THEN 20220
20230 A = (4096 *12) +(256 *SL): PRINT H$: CALL A: GOTO 62000
21000 H$ = CHR$(12):EL$ = CHR$(14):EP$ = CHR$(15):L$ = CHR$(17):R$ = CHR$(18) + CHR$(3) +"3":E$ = CHR$(5):W$ = CHR$(23):B$ = CHR$(25):U$ = CHR$(26):CL$ = CHR$(3):WH$ = CL$ +"3":GU$ = CL$ +"1":VI$ = CL$ +"2":OU$ = CL$ +"5":BU$ = CL$ +"6": CALL 3584: POKE 3594,28: POKE 3595,17: RETURN
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME : VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
Text found in Microzone__Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club.do/WH.bas:
0 ONERR GOTO 62000
2 REM COPYRIGHT 1984 SCHOLASTIC INC
10 HIMEM: 36352
20 D$ = CHR$(4)
24 SL = PEEK(47081)/16: IF SL <1 OR SL >7 THEN SL = 6
26 DR = 1: POKE 46989,SL: POKE 46990,DR
30 REM
35 IF C >500 THEN 39
37 IF PEEK( -16384) >127 THEN C = 2000
38 C = C +1: GOTO 35
39 IF PEEK( -16384) = 144 THEN PRINT "RUNPPG"
40 POKE 103,1: POKE 104,64: POKE 16384,0: POKE -16368,0
70 PRINT CHR$(4)"RUNHELLO2": END
62000 SL = PEEK(47081)/16: POKE -16368,0: IF SL <1 OR SL >7 THEN SL = 6
62010 PRINT CHR$(12): PRINT CHR$(4)"CLOSE": PRINT CHR$(4)"PR#0": PRINT CHR$(4)"IN#0": PRINT CHR$(4): TEXT : HOME
62020 VTAB 11: HTAB 4: PRINT "THERE IS A PROBLEM WITH YOUR DISK": PRINT : HTAB 9: PRINT "PRESS ANY KEY TO RESTART": WAIT -16384,128:A = 49152 +(256 *SL): CALL A
62021 GOTO 62021
- Addeddate
- 2014-06-21 05:28:54
- Emulator
- apple2e
- Emulator_ext
- do
- Identifier
- a2_Microzone_Northwoods_Adventure_1984_Scholastic_Side_A_cr_Black_Bag_Club
- Scanner
- Internet Archive Python library 0.6.5
comment
Reviews
896 Views
1 Favorite
DOWNLOAD OPTIONS
IN COLLECTIONS
Apple II Library: Compilation Disks (Games) The Software Library: Apple Computer Software Library The Emulation StationUploaded by Jason Scott on